Blob shadow projector is not projecting properly

[Hertzole]

Hi

I just imported the projectors, in effects, from the standard assets and I can’t get it to work. I honestly can’t give more info than that since I can describe by words what’s going on. So here’s a picture!

That is what the brand new and unedited blob shadow projector prefab causes.

Here’s what the texture import settings are. (it is the same for both the shadow texture and falloff)

and here is the projector component itself.
Since no more attachments were allowed, here’s a link to it. Link!

What am I doing wrong? It works in another project but not in this one. It is driving me insane!

[jgthibodeau]

Getting this exact bug now. Tried reinstalling completely and it’s still there, but my searches have found no solution.

[Hertzole]

I found a fix.
Since I had an older project with these blob shadows and it worked there, I got the shader from that and replaced it with that. For some reason, the shader seemed to be broken.

Here’s the shader code. Just replace it with the old shader code you already got.

Shader "Projector/Multiply" {
	Properties{
		_ShadowTex("Cookie", 2D) = "gray" {}
		_FalloffTex("FallOff", 2D) = "white" {}
	}
	Subshader {
		Tags { "Queue" = "Transparent" }
		Pass {
			ZWrite Off
			ColorMask RGB
			Blend DstColor Zero
			Offset -1, -1

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile_fog
			#include "UnityCG.cginc"

			struct v2f {
				float4 uvShadow : TEXCOORD0;
				float4 uvFalloff : TEXCOORD1;
				UNITY_FOG_COORDS(2)
				float4 pos : SV_POSITION;
			};

			float4x4 _Projector;
			float4x4 _ProjectorClip;

			v2f vert(float4 vertex : POSITION)
			{
				v2f o;
				o.pos = mul(UNITY_MATRIX_MVP, vertex);
				o.uvShadow = mul(_Projector, vertex);
				o.uvFalloff = mul(_ProjectorClip, vertex);
				UNITY_TRANSFER_FOG(o,o.pos);
				return o;
			}

			sampler2D _ShadowTex;
			sampler2D _FalloffTex;

			fixed4 frag(v2f i) : SV_Target
			{
				fixed4 texS = tex2Dproj(_ShadowTex, UNITY_PROJ_COORD(i.uvShadow));
				texS.a = 1.0 - texS.a;

				fixed4 texF = tex2Dproj(_FalloffTex, UNITY_PROJ_COORD(i.uvFalloff));
				fixed4 res = lerp(fixed4(1,1,1,0), texS, texF.a);

				UNITY_APPLY_FOG_COLOR(i.fogCoord, res, fixed4(1,1,1,1));
				return res;
			}
			ENDCG
		}
	}
}