Bump Spec Alpha

Unity Engine
1

Hey everyone,

I couldn’t find a Bump Specular Alpha shader for mobile, so I started messing around with one. I haven’t tested it on anything complicated like characters or full levels but it works well enough for punching a hole through a plane.

Here is the shader:

// Simplified Bumped Specular shader. Differences from regular Bumped Specular one:
// - No Main Color nor Specular Color
// - Specular lighting directions are approximated per vertex
// - Supports alpha channel
// - Normalmap uses Tiling/Offset of the Base texture

Shader "Mobile/Bump Specular Alpha All Lights" {
Properties {
	_Shininess ("Shininess", Range (0.03, 1)) = 0.078125
	_MainTex ("Base (RGB) Gloss (A)", 2D) = "white" {}
	_BumpMap ("Normalmap", 2D) = "bump" {}
}
SubShader { 
	Tags { "Queue"="Transparent" "RenderType"="TransparentCutout" }
	Cull Back
	ZWrite On
	ZTest LEqual
	ColorMask RGBA
	Blend SrcAlpha OneMinusSrcAlpha
	LOD 250
	
CGPROGRAM
#pragma surface surf MobileBlinnPhong exclude_path:prepass halfasview
// Add noforwardadd to use only 1 directional light + vertex lights

inline fixed4 LightingMobileBlinnPhong (SurfaceOutput s, fixed3 lightDir, fixed3 halfDir, fixed atten)
{
	fixed diff = max (0, dot (s.Normal, lightDir));
	fixed nh = max (0, dot (s.Normal, halfDir));
	fixed spec = pow (nh, s.Specular*128) * s.Gloss;
	
	fixed4 c;

	c.rgb = (s.Albedo * _LightColor0.rgb * diff + _LightColor0.rgb * spec) * (atten*2);
	c.a = s.Alpha;
	return c;
}

sampler2D _MainTex;
sampler2D _BumpMap;
half _Shininess;
half Alpha;

struct Input {
	float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
	fixed4 tex=tex2D(_MainTex,(IN.uv_MainTex.xyxy).xy);
	o.Albedo = tex.rgb;
	o.Gloss = tex.a;
	o.Specular = _Shininess;
	o.Normal = UnpackNormal (tex2D(_BumpMap, IN.uv_MainTex));
	o.Alpha = tex.a;

}
ENDCG
}

FallBack "Mobile/Bumped Specular"
}
2

There’s a problem when using per-pixel lights (directional is okay). Using them causes the invisible area to become semi-transparent. I’m not sure if this is an issue with the shader or how Unity handles per-pixel lighting. Any suggestions?

3

This one works better. I don’t know if having #pragma alpha makes it more expensive, though?

// - no Main Color nor Specular Color
// - specular lighting directions are approximated per vertex
// - Normalmap uses Tiling/Offset of the Base texture
// - Alpha Support

Shader "Mobile/Bump Spec Alpha All Lights" {
Properties {
	_Shininess ("Shininess", Range (0.03, 1)) = 0.078125
	_MainTex ("Base (RGB) Gloss (A)", 2D) = "white" {}
	_BumpMap ("Normalmap", 2D) = "bump" {}
}
SubShader { 
	Tags { "Queue"="Transparent" "RenderType"="Transparent" }
	LOD 250
	
CGPROGRAM
#pragma surface surf MobileBlinnPhong exclude_path:prepass halfasview alpha
// Add noforwardadd to use only 1 directional light + vertex lights

inline fixed4 LightingMobileBlinnPhong (SurfaceOutput s, fixed3 lightDir, fixed3 halfDir, fixed atten)
{
	fixed diff = max (0, dot (s.Normal, lightDir));
	fixed nh = max (0, dot (s.Normal, halfDir));
	fixed spec = pow (nh, s.Specular*128) * s.Gloss;
	
	fixed4 c;
	c.rgb = (s.Albedo * _LightColor0.rgb * diff + _LightColor0.rgb * spec) * (atten*2);
	c.a = 0.0;
	return c;
}

sampler2D _MainTex;
sampler2D _BumpMap;
half _Shininess;

struct Input {
	float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
	fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
	o.Albedo = tex.rgb;
	o.Gloss = tex.a;
	o.Alpha = tex.a;
	o.Specular = _Shininess;
	o.Normal = UnpackNormal (tex2D(_BumpMap, IN.uv_MainTex));
}
ENDCG
}

FallBack "Mobile/VertexLit"
}