Can you make an object or Prefab be less effected by the atmosphere?

Questions & Answers
1

Specifically I want one type of prefab be less effected by the Skybox material than any other object in the game. I don’t want it to be completely unaffected just less so than other objects.

2

Here is my answer you can add stuff in for alpha I had no need of that though

Shader "Example/CustomGI_ToneMapped" {
	Properties{
		_MainTex("Albedo (RGB)", 2D) = "white" {}
	_Gain("Lightmap tone-mapping Gain", Float) = 1
		_Knee("Lightmap tone-mapping Knee", Float) = 0.5
		_Compress("Lightmap tone-mapping Compress", Float) = 0.33
		_Color("Color", Color) = (1,1,1,1)
		_Glossiness("Smoothness", Range(0,1)) = 1
		_Metallic("Metallic", Range(0,1)) = 1
	}
		SubShader{
		Tags{ "RenderType" = "Opaque" }

		CGPROGRAM
#pragma surface surf StandardToneMappedGI

#include "UnityPBSLighting.cginc"
#pragma target 3.0

		half _Gain;
	half _Knee;
	half _Compress;
	sampler2D _MainTex;

	inline half3 TonemapLight(half3 i) {
		i *= _Gain;
		return (i > _Knee) ? (((i - _Knee)*_Compress) + _Knee) : i;
	}

	inline half4 LightingStandardToneMappedGI(SurfaceOutputStandard s, half3 viewDir, UnityGI gi)
	{
		return LightingStandard(s, viewDir, gi);
	}

	inline void LightingStandardToneMappedGI_GI(
		SurfaceOutputStandard s,
		UnityGIInput data,
		inout UnityGI gi)
	{
		LightingStandard_GI(s, data, gi);

		gi.light.color = TonemapLight(gi.light.color);
#ifdef DIRLIGHTMAP_SEPARATE
#ifdef LIGHTMAP_ON
		gi.light2.color = TonemapLight(gi.light2.color);
#endif
#ifdef DYNAMICLIGHTMAP_ON
		gi.light3.color = TonemapLight(gi.light3.color);
#endif
#endif
		gi.indirect.diffuse = TonemapLight(gi.indirect.diffuse);
		gi.indirect.specular = TonemapLight(gi.indirect.specular);
	}

	fixed4 _Color;
	half _Glossiness;
	half _Metallic;
	struct Input {
		float2 uv_MainTex;
	};

	void surf(Input IN, inout SurfaceOutputStandard o) {

		o.Albedo = tex2D(_MainTex, IN.uv_MainTex) * _Color;
		o.Smoothness = _Glossiness;
		o.Metallic = _Metallic;
	}
	ENDCG
	}
		FallBack "Diffuse"
}