Diffuse + Specular + normal map + Alpha cutout ?

Unity Engine
1

Hello, I need to use three textures on one house model.
Diffuse which includes alpha map,
Bump normal map,
And specular map.

I see similar in shaders of unity transparent>cutout>bumped specular, but it does not consist entry for specular texture. (it makes whole house shiny).

Is it possible in unity ?

1709742--107617--unity.jpg
1709742--107617--unity.jpg1432×730 233 KB

2

It seems that shader actually uses the alpha in the diffuse texture for both the gloss and the cutout. Not very useful. Something like this should work, but I didn’t test it:

Shader "Transparent/Cutout/Bumped Specular Split" {
Properties {
   _Color ("Main Color", Color) = (1,1,1,1)
   _SpecColor ("Specular Color", Color) = (0.5, 0.5, 0.5, 0)
   _Shininess ("Shininess", Range (0.01, 1)) = 0.078125
   _MainTex ("Base (RGB) TransGloss (A)", 2D) = "white" {}
   _BumpMap ("Normalmap", 2D) = "bump" {}
   _GlossMap ("Glossmap", 2D) = "black" {}
   _Cutoff ("Alpha cutoff", Range(0,1)) = 0.5
}

SubShader {
   Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
   LOD 400
   
CGPROGRAM
#pragma surface surf BlinnPhong alphatest:_Cutoff
#pragma exclude_renderers flash

sampler2D _MainTex;
sampler2D _BumpMap;
sampler2D _GlossMap;
fixed4 _Color;
half _Shininess;

struct Input {
   float2 uv_MainTex;
   float2 uv_BumpMap;
};

void surf (Input IN, inout SurfaceOutput o) {
   fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
   o.Albedo = tex.rgb * _Color.rgb;
   o.Gloss = tex2D(_GlossMap, IN.uv_MainTex).a;
   o.Alpha = tex.a * _Color.a;
   o.Specular = _Shininess;
   o.Normal = UnpackNormal(tex2D(_BumpMap, IN.uv_BumpMap));
}
ENDCG
}

FallBack "Transparent/Cutout/VertexLit"
}

The idea is that the gloss is stored in the alpha of the glossmap.

1 Like