FixedFunction Decal/plain-color lerp by alpha

Graphics Shaders & Materials
1

I’m not good on fixed function but need to have a FF fallback for this shader. It takes an image with alpha and a color and where the image is transparent the color is drawn - thus the lerp function.
So can anyone help with lerping betweening texture and color, based on texture-alpha, in FF or confirm if it is possible?

The Shader:

Shader "ClothingDecal" {
Properties {
	_Color ("Main Color", Color) = (1,1,1,1)
	_MainTex ("Base (RGBA)", 2D) = "white" {}
}

SubShader {
	Tags { "RenderType"="Opaque" }
	LOD 250
	
CGPROGRAM
#pragma surface surf Lambert

sampler2D _MainTex;
float4 _Color;

struct Input {
	float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
	half4 c = _Color;
	half4 decal = tex2D(_MainTex, IN.uv_MainTex);
	c.rgb = lerp(c.rgb, decal.rgb, decal.a);

	o.Albedo = c.rgb;
	o.Alpha = c.a;
}
ENDCG
}

Fallback "Diffuse"//need alternative that works!
}
2 
Shader "ClothingDecal" {
	
Properties { 
    _Color ("Main Color", Color) = (1,1,1,1) 
    _MainTex ("Base (RGBA)", 2D) = "white" {} 
} 

Category { 
	Tags { "RenderType"="Opaque" } 
	LOD 250 

	SubShader {    
		CGPROGRAM
		#pragma surface surf Lambert 
		
		sampler2D _MainTex; 
		float4 _Color; 
		
		struct Input { 
		    float2 uv_MainTex; 
		}; 
		
		void surf (Input IN, inout SurfaceOutput o) { 
		    half4 c = _Color; 
		    half4 decal = tex2D(_MainTex, IN.uv_MainTex); 
		    c.rgb = lerp(c.rgb, decal.rgb, decal.a); 
		
		    o.Albedo = c.rgb; 
		    o.Alpha = c.a; 
		} 
		ENDCG
	}
	
	SubShader {
	    Lighting On
	    Material {
	        Ambient (1,1,1)
	        Diffuse (1,1,1)
	    }
	    
	    Pass {
	    	SetTexture[_MainTex] {
	    		ConstantColor [_Color]
	    		Combine texture Lerp(texture) constant, constant
	    	}
	        SetTexture[_] {Combine previous * primary Double, previous}
	    }
	}
}

}

That doesn’t account for 1-texture cards, but people don’t need to be running Unity content on computers like that. You can probably figure out what to edit, for a third SubShader, if you disagree, but let me know if you actually care about providing content to those users, and don’t know what to do to take lighting out, which is what I’d do.

3

Perfect, thanks.
It seems slight overkill to even support Fixed Function these days, but when doing web content it’s good to support almost everyone!