Geometry shader examples for OpenGL

Unity Engine
1

Howdy,
So with the 5.3 update, Mac GPUs that support OpenGL 4.1 should be able to use geometry shaders in Unity.

I want to start playing with this but having difficulty trying to find me some examples to get me started. I’m constantly getting a “Shader is not supported on this GPU (none of subshaders/fallbacks are suitable)” errors in the shaders that I’ve found online (I have a mid 2014 Macbook Pro so I’ve got OpenGL 4.1 which should be able to run geometry shaders).

Does someone have any simple shader examples that could help me out? Don’t need anything fancy, just something that uses the geometry shader.

2

Anybody?

3

Hey,
first of all, geometry shaders don’t work with surface shaders. You have to use standard combination of vertex, geometry, pixel shaders and handle everything yourself. So getting it to interact with lights can be a bit tricky for example. Also, the cross-compilation from HLSL to GLSL seems to be buggy at the moment, so not every valid code will compile and you have to try to rewrite it somehow. With that being said, here is a simple working shader (a bit hacky to get over compiler issues). The geometry shader computes common normal vector for every triangle.

Shader "test/MyShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma geometry geom
           
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 normal : NORMAL;
                float2 uv : TEXCOORD0;
                float3 worldPosition : TEXCOORD1;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
           
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.normal = v.normal;
                o.worldPosition = mul(_Object2World, v.vertex).xyz;
                return o;
            }

            [maxvertexcount(3)]
            void geom(triangle v2f input[3], inout TriangleStream<v2f> OutputStream)
            {
                v2f test = (v2f)0;
                float3 normal = normalize(cross(input[1].worldPosition.xyz - input[0].worldPosition.xyz, input[2].worldPosition.xyz - input[0].worldPosition.xyz));
                for(int i = 0; i < 3; i++)
                {
                    test.normal = normal;
                    test.vertex = input[i].vertex;
                    test.uv = input[i].uv;
                    OutputStream.Append(test);
                }
            }
           
            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);

                float3 lightDir = float3(1, 1, 0);
                float ndotl = dot(i.normal, normalize(lightDir));

                return col * ndotl;
            }
            ENDCG
        }
    }
}
1 Like
4

You my friend are a gentleman and a scholar! That’s exactly what I looking for.

I wasn’t sure what the input to the geometry shader should be, how to output the vertices etc.

5

@Michal_1 desperately trying to get any geometry shader working on mac, but keep running into 2 things:
Shader is not supported on this GPU, and Metal: Error creating pipeline state (Custom/Geom_Grass): Vertex attribute POSITION0(0) is missing from the vertex descriptor.
I tried running this one and got the Shader not supported… any advice?
EDIT: ok so after adding a fallback to yours it compiled. but still not for metal :frowning:
my specs are:
MacBook Pro (Retina, 15-inch, Early 2013)
2,7 GHz Intel Core i7
16 GB 1600 MHz DDR3
NVIDIA GeForce GT 650M 1024 MB
Intel HD Graphics 4000 1536 MB
i wouldn’t thing my macbook is the problem.

example of shader where i get the pipeline error:

Shader "Custom/Geom_Grass" {
    Properties {
        _MainTex ("Main Texture", 2D) = "white"{}
        _Color ("Color", Color) = (1,1,1,1)
        _GrassHeight ("Grass Height", float) = 3
        _GrassWidth ("Grass Width", float) = 0.1
        _Glossiness ("Smoothness", Range(0,1)) = 0.5
        _Metallic ("Metallic", Range(0,1)) = 0.0
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 200
        Cull off
        ZWrite off

        Pass
        {
            CGPROGRAM
            // Physically based Standard lighting model, and enable shadows on all light types
            #pragma vertex vert
            #pragma geometry geom
            #pragma fragment frag
            #pragma target 5.0
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            float4 _Color;
            float3 _worldPos;
            float _GrassHeight;
            float _GrassWidth;

            struct data{
                float3 pos;
            };

            StructuredBuffer<data> buff_Points;

            struct input {
                float4 pos:SV_POSITION;
                float2 uv:TEXCOORD0;
                UNITY_FOG_COORDS(1)
            };

            sampler2D _MainTex;
            half _Glossiness;
            half _Metallic;

            input vert(uint id : SV_VertexID)
            {
                input o;
                o.pos = float4(buff_Points[id].pos +_worldPos, 1);
                return o;
            }
            [maxvertexcount(3)]
            void geom(point input p[1], inout TriangleStream<input> triStream)
            {
                float4 p1 = p[0].pos.xyzw + float4(0,_GrassHeight,0,0);
                float4 p2 = p[0].pos.xyzw + float4(-_GrassWidth,0,0,0);
                float4 p3 = p[0].pos.xyzw + float4(_GrassWidth,0,0,0);
                input pIN;
                pIN.pos = mul(UNITY_MATRIX_VP, p1);
                pIN.uv = float2(0,0);
                UNITY_TRANSFER_FOG(pIN,pIN.pos);
                triStream.Append(pIN);

                pIN.pos = mul(UNITY_MATRIX_VP, p2);
                pIN.uv = float2(0,1);
                UNITY_TRANSFER_FOG(pIN,pIN.pos);
                triStream.Append(pIN);

                pIN.pos = mul(UNITY_MATRIX_VP, p3);
                pIN.uv = float2(1,0);
                UNITY_TRANSFER_FOG(pIN,pIN.pos);
                triStream.Append(pIN);
            }

            float4 frag(input i):COLOR
            {
                fixed4 col = tex2D(_MainTex, i.uv)*_Color;
                UNITY_APPLY_FOG(i.foCoord, col);
                return col;
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}
6

Regarding “Shader is not supported on this GPU”. That graphics card reports a SystemInfo.graphicsShaderLevel of 45 (Metal / OpenGL ES 3.1 capabilities (Shader Model 3.5 + compute shaders)) when the editor is running Metal, and 46 (OpenGL 4.1 capabilities (Shader Model 4.0 + tessellation)) when the editor is running OpenGL.

Geometry shaders do work when running under OpenGL, but not under Metal (because shader model 3.5 doesn’t support them). Ironically the reverse is true for compute shaders.

I know this is an old post, but I found it so someone else might too…

3 Likes