Glow map shader for Unity basic?

Hi,

So I was wondering, is it possible to create a shader that takes a glow map, much like the self illumination shaders take, but create an effect a bit closer to something like this?
(see the webGL demo, playign around with the settings a bit can create a really nice glow effect.)

I’m looking for something like this for a character with a lot of glowing symbols/runes. It’d be nice to use UV coord’s for the glow effect.

Is there any way to achieve this in Unity basic?

Thanks in advance,

Nick

In its most simple form, the effect can be achieved with a basic shader, with an added emission map property. Any additional blur effects you might need are not included:

Shader "Custom/EmissionShader" {
    Properties {
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _EmissionTex ("Emission Map (RGB)", 2D) = "white" {}
        _Bump ("Bump", 2D) = "bump" {}
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 200
 
        CGPROGRAM
        #pragma surface surf Lambert
 
        sampler2D _MainTex;
        sampler2D _EmissionTex;
        sampler2D _Bump;
 
        struct Input {
            float2 uv_MainTex;
            float2 uv_EmissionTex;
            float2 uv_Bump;
        };
 
        void surf (Input IN, inout SurfaceOutput o) {
            half4 c = tex2D (_MainTex, IN.uv_MainTex);
            half4 em = tex2D (_EmissionTex, IN.uv_EmissionTex);
            o.Normal = UnpackNormal(tex2D(_Bump, IN.uv_Bump));
 
            o.Albedo = c.rgb;
            o.Alpha = c.a;
            o.Emission=em.rgb;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

This is the produced effect

alt text
alt text
And this is the produced effect in a more dark environment.

alt text

You can either do the rest of the work in the textures, or play around with the shader code to create the effect you want.