How are the minimum and maximum coordinates of ComputeScreenPos determined

Unity Engine
1

Hello everyone!

My assumption was that ComputeScreenPos(o.vertex).x would be a value between 0 and 1, 0 being the left most pixel of the screen and 1 being the right most pixel of the screen.

It appears that this is incorrect, as the following shader appears to only put a gradient on about one-tenth of the left side of the screen (in perspective camera mode). In orthographic camera mode this shader works as expected, with a gradient from left to right.

What are the minimum and maximum XYZW coords of ComputeScreenPos and what parameters can we use to normalize at least the XY coords?

Thanks for reading!

struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                float4 screenPos : TEXCOORD1;
            };
         
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                o.screenPos = ComputeScreenPos(o.vertex);
                return o;
            }
         
            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = float4(i.screenPos.x,i.screenPos.x, i.screenPos.x, 1);

                return col;
            }
2

While I cannot explain exactly why at this stage, it appears that the fourth coordinate in the float4 returned by ComputeScreenPos can be used to make o.screenPos.xy return valuable results from 0 to 1.

//Updated code to make coordinates between 0 and 1
o.screenPos = ComputeScreenPos(o.vertex);
o.screenPos.xyz /= o.screenPos.w;

1 Like
3

You should only do this part in the fragment shader, and not in the vertex shader. The reason is because of the non-linear nature of projection (aka clip) space. If you do the divide in the vertex shader it might look right in some cases, specifically on quads that are parallel with the camera plane, but anything more complicated will end up with the screenPos looking distorted.

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };
            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                float4 screenPos : TEXCOORD1;
            };
       
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                o.screenPos = ComputeScreenPos(o.vertex);
                return o;
            }
       
            fixed4 frag (v2f i) : SV_Target
            {
                float2 screenPos = i.screenPos.xy / i.screenPos.w;
                fixed4 col = fixed4(screenPos.xxx, 1);
                return col;
            }

In projection space, what the UnityObjecToClipPos() function returns, the x and y components go from -w to +w. The ComputeScreenPos() basically just does “xy = (xy + w) * 0.5” to move them from that -w to +w range to a 0.0 to +w range, plus some extra code to handle flipped projection space (it’s a “fun” topic, but sometimes rendering happens upside down, don’t worry about it), and deal with single pass stereo.

1 Like