how can i make the screen black white

i dont want fade, i need to make only black/white screen. but i donot have pro, may i need pro?

Yup, if you want to do this as an image effect, you need pro. Otherwise you'll have to just actually use all black & white texures & lights in your scene.

There's one other method which springs to mind, which is that this could possibly be done by writing some custom surface shaders which allow you to blend to black & white. This would have to be done with all the materials in your scene, and would be a bit awkward, but might just work!

-- EDIT --

Here you go, a shader which has a fader to blend from colour to black & white:

Shader "Black & White/Diffuse" {
    Properties {
        _Color ("Main Color", Color) = (1,1,1,1)
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _bwBlend ("Black & White blend", Range (0, 1)) = 0
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        #pragma surface surf Lambert

        sampler2D _MainTex;
        float4 _Color;
        float _bwBlend;

        struct Input {
            float2 uv_MainTex;
        };

        void surf (Input IN, inout SurfaceOutput o) {
            half4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
            half lum = c.r*.3 + c.g*.59 + c.b*.11;
            half3 bw = half3( lum, lum, lum );

            o.Albedo = lerp(c.rgb, bw, _bwBlend);
            o.Alpha = c.a;
        }
        ENDCG
    }

    Fallback "VertexLit"
}

You can set the fader value from a script by using the Material.SetFloat function, like this:

renderer.material.SetFloat("_bwBlend", 0.5f );

If you want to use other types of shaders (eg, specular, transparent, etc) you'd have to write a black & white fader version of each type of shader.

I know this is an old topic but for others looking for a solution for there free version. to get Non-gray scale black and white, you can simply, create a camera, change the background to white and disable the lights.