How do I copy depth to the camera target in Unity's SRP?

Unity Engine
1

(Copied from r/Unity3D because no one replied me there)

Hello, I’m trying to copy the depth buffer to camera target after post-processing in my render pipeline, but instead it’s just black. Thus, the gizmos (that I draw through UnityEditor.Handles.DrawGizmos btw) aren’t affected by depth unless I disable post-processing. I render the depth buffer to a different texture for shaders to use, but that’s about it. Also there’s an odd thing is that when I draw depth of field (which is in second pass btw) the buffer does get copied to that texture according to frame debugger, but when I don’t render it it does the same to a different effect. I’m using Unity 2019.1.9f1, by the way. Maybe it was fixed in future releases, but I’m not updating with my current internet, no thanks.

Things I’ve already tried:

  • Rendering depth into BuiltinRenderTextureType.Depth. It does nothing and instead sends a warning in console about target type 3 not existing.
  • Not using CommandBuffer.Blit and doing it manually (render a fullscreen quad with a material). Same thing minus the second pass mystery.
  • Copying depth with a pass in the end. No depth buffer at all.
  • Setting a render target to a destination texture’s color buffer and source’s depth buffer. As expected, nothing, even though others (including the official documentation) say it works. Might be just a misunderstanding, English isn’t my mother tongue.
  • Same as 4, but instead setting a render target’s depth to a camera target. Result is the same.
  • Copying depth in every pass. Same as blitting it, including the second pass mystery.

Could someone help me, please? I feel like I’m going crazy because of this.

P.S.: No, I don’t want to use LWRP/HDRP, I don’t know how to write custom renderers for the former so I can have toon shaders and I don’t know how to access lights in a shader graph so I calculate lighting myself, this is why I decided to make my own RP. If someone tells me how to do that, it would also be very nice and I might move to LWRP.

P.P.S.: I didn’t find any tutorials for post-processing with SRP online and my current system is based on researching LWRP.

2

OK, I will probably have to rewrite the entire thing. I messed up and for whatever reason the entire image slowly turns white, similar how it does in Source games when you go out-of-bounds if you have HDR on. For now I’ll restrain from doing any post-processing until this question is solved or someone has a proper tutorial on how to do post-processing in SRP.

3

After doing more research, it turned out I was stupid. ZWrite was set to off in my copy depth shader. Setting it to on did not add a depth buffer in the camera target unfortunately (probably because it doesn’t have a depth buffer to begin with?), but gizmos now work as intended, fading out if occluded and everything. This question is now solved.

4

Hey! I’m facing with the same bloody issue.
And looks like you’ve made some progress with it. Can you please provide some details about how exactly did you solve it? If I understand correct you copying depth buffer to BuiltinRenderTextureType.CameraTarget some where before Drawing Gizmos?

5

What type of issue do you have? I got similar mechanic working in my srp, may be I can help.

6

I’m using Custom Renderer pipeline with MRT (so I create a depth buffer to attach as render target) and the problem is that now gizmos aren’t affected by depth, as the OP mentioned.

I’m assuming that I rather need to copy my existing depth buffer to be used later when gizmos rendered, or I need to hook into one of the BuiltinRenderTextureType. When I’m trying to copy/ renderer whatever to BuiltinRenderTextureType.Depth I’m recieving “target type 3 not existing” error in console.

Have you faced smth similar?

7

Here is how it works for me (CustomDraw is just my Blit() analog)

#if UNITY_EDITOR
        if (camera.cameraType == CameraType.SceneView && Handles.ShouldRenderGizmos())
        {
            CustomDraw(BuiltinRenderTextureType.CameraTarget, matFxCopyDepth);
            ProcessBuffer();

            context.DrawGizmos(camera, GizmoSubset.PreImageEffects);
            context.DrawGizmos(camera, GizmoSubset.PostImageEffects);
        }
#endif

        void ProcessBuffer()
        {
            context.ExecuteCommandBuffer(buffer);
            buffer.Clear();
        }

        void CustomDraw(RenderTargetIdentifier target, Material material, int pass = 0)
        {
            buffer.SetRenderTarget(target);
            buffer.DrawProcedural(Matrix4x4.identity, material, pass, MeshTopology.Triangles, 3);
        }

DepthTexture is preliminarily set as global, so shader can use it. You probably should try Blit(depthTexture, BuiltinRenderTextureType.CameraTarget, copyDepthMaterial) depending on how your shader works.

8

Unfortunately is doesn’t help. I’ve been trying similar approach, and it doesn’t seems to have any effect, so maybe there is an issue with my CopyDepth shader. Here is it:

Are you drawing gizmos after resolving the MTR?

Shader "Hidden/CopyDepth" {
    SubShader {
        Cull Off
        ZWrite Off
        ZTest Always

        HLSLINCLUDE
        #include "../ShaderLibrary/Common.hlsl"
        ENDHLSL

        Pass {
            Name "Copy Depth"

            HLSLPROGRAM
            #pragma target 3.5
            #pragma vertex vert
            #pragma fragment frag

            TEXTURE2D (_MainTex);
            SAMPLER (sampler_linear_clamp);

            struct Varyings {
                float4 vertex : SV_POSITION;
                float2 uv : VAR_FX_UV;
            };

            Varyings vert (uint vertexID : SV_VertexID) {
                Varyings output;

                output.vertex = float4(
                    vertexID <= 1 ? -1.0 : 3.0,
                    vertexID == 1 ? 3.0 : -1.0,
                    0.0, 1.0
                );

                output.uv = float2(
                    vertexID <= 1 ? 0.0 : 2.0,
                    vertexID == 1 ? 2.0 : 0.0
                );

                if (_ProjectionParams.x < 0.0) {
                    output.uv.y = 1.0 - output.uv.y;
                }
                return output;
            }

            float4 frag (Varyings i) : SV_TARGET {
                float depth = SAMPLE_DEPTH_TEXTURE(_MainTex, sampler_linear_clamp, i.uv);
                return float4(depth.xxx, 1);
            }

            ENDHLSL
        }
    }
}
9

@Egnech It’s the shader indeed. First of all, it should write to Z buffer. Frag must output float into SV_DEPTH, try this:

Shader "Hidden/CopyDepth" {
    SubShader {
        Cull Off
        ColorMask 0
        ZWrite On
        ZTest Always

        HLSLINCLUDE
        #include "../ShaderLibrary/Common.hlsl"
        ENDHLSL

        Pass {
            Name "Copy Depth"

            HLSLPROGRAM
            #pragma target 3.5
            #pragma vertex vert
            #pragma fragment frag

            TEXTURE2D (_MainTex);
            SAMPLER (sampler_linear_clamp);

            struct Varyings {
                float4 vertex : SV_POSITION;
                float2 uv : VAR_FX_UV;
            };

            Varyings vert (uint vertexID : SV_VertexID) {
                Varyings output;

                output.vertex = float4(
                    vertexID <= 1 ? -1.0 : 3.0,
                    vertexID == 1 ? 3.0 : -1.0,
                    0.0, 1.0
                );

                output.uv = float2(
                    vertexID <= 1 ? 0.0 : 2.0,
                    vertexID == 1 ? 2.0 : 0.0
                );

                if (_ProjectionParams.x < 0.0) {
                    output.uv.y = 1.0 - output.uv.y;
                }
                return output;
            }

            float frag (Varyings i) : SV_DEPTH {
                float depth = SAMPLE_DEPTH_TEXTURE(_MainTex, sampler_linear_clamp, i.uv);
                return depth;
            }

            ENDHLSL
        }
    }
}
1 Like
10

And it work like a charm. Thank you!

1 Like