How to create a shader that does not test for z-depth but obeys UI Mask

So perhaps slightly mutually exclusive but I am trying to make a shader for my UI. The idea being that the UI elements that use the shader will appear over top everything else in the game. That much I have working using this:

// Unlit alpha-blended shader.
// - no lighting
// - no lightmap support
// - supports tint color

Shader "Unlit/Transparent HUD" {

	Properties
	{
		_MainTex ("Base (RGB), Alpha (A)", 2D) = "white" {}
		_Color ("Main Color", Color) = (0.5,0.5,0.5,0.5)
	}
	
	SubShader
	{
		LOD 100

		Tags
		{
			"Queue" = "Transparent+99"
			"IgnoreProjector" = "True"
			"RenderType" = "Transparent"
		}
		
		Cull Off
		Lighting Off
		ZTest Always
		ZWrite Off
		Fog { Mode Off }
		Offset -1, -1
		Blend SrcAlpha OneMinusSrcAlpha

		Pass
		{
			CGPROGRAM
				#pragma vertex vert
				#pragma fragment frag
				
				#include "UnityCG.cginc"
	
				struct appdata_t
				{
					float4 vertex : POSITION;
					float2 texcoord : TEXCOORD0;
					fixed4 color : COLOR;
				};
	
				struct v2f
				{
					float4 vertex : SV_POSITION;
					half2 texcoord : TEXCOORD0;
					fixed4 color : COLOR;
				};
	
				sampler2D _MainTex;
				float4 _MainTex_ST;
				fixed4 _Color;
				
				v2f vert (appdata_t v)
				{
					v2f o;
					o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
					o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
					o.color = v.color;
					return o;
				}
				
				fixed4 frag (v2f i) : COLOR
				{
					fixed4 col = tex2D(_MainTex, i.texcoord) * i.color * _Color;
					return col;
				}
			ENDCG
		}
	}
	
	
}

The problem I am running into is that this shader also ignores the UI > Mask component so if I have a list of buttons using this shader they will not be hidden when they are scrolled out of view. So my question is, can I edit this shader to obey the mask but continue to draw over everything else?

I’m afraid I cannot address the UI Mask component you are talking about, as I have not used it. I achieved this effect using the “stencil” buffer in shaders. This method consists of TWO shaders, one is the “STENCIL HOLE”, the other would be applied to your “TEXT” (though it does not HAVE to be text, of course). Only “text” that is covered with the “stencil hole” (or un-convered if your modify the code slightly), as far as the camera is concerned, will be drawn. Note: you may need to create new meshes with a renderer using the “Stencil Hole” Shader

Code for the “STENCIL HOLE” shader:

Shader "Custom/StencilHole" { //also used for silhouetted objects
	Properties {
		
	}
	SubShader {

		// Write the value 1 to the stencil buffer
		Stencil
		{
			Ref 1
			Comp Always
			Pass Replace
		}

		Tags { "Queue" = "Geometry-1" }  // Write to the stencil buffer before drawing any geometry to the screen
		ColorMask 0 // Don't write to any colour channels
		ZWrite Off // Don't write to the Depth buffer

		Pass {}
	} 
	FallBack "Diffuse"
}

Code for the “TEXT” shader:

Shader "GUI/TextCullStencilOverlay" {

	Properties {
		_MainTex ("Font Texture", 2D) = "white" {}
		_Color ("Text Color", Color) = (1,1,1,1)
	}
 
	SubShader {
		// Only render pixels whose value in the stencil buffer equals 1.
		Stencil {
		  Ref 1
		  Comp Equal
		}
		Tags { "Queue"="Overlay+1" "IgnoreProjector"="True" "RenderType"="Transparent" }
		Lighting Off Cull back ZWrite Off Fog { Mode Off }
		Blend SrcAlpha OneMinusSrcAlpha
		Pass {
			Color [_Color]
			ColorMaterial AmbientAndDiffuse
			SetTexture [_MainTex] {
				combine primary, texture * primary
			}
		}
	}
}

The answer here might be of interest to you: World Space canvas on top of "everything" ? - Questions & Answers - Unity Discussions

I’m not sure if it solves your masking problem though.

You can control render order with renderqueue. You can make another UI button shader with:
“Queue” = “Transparent+98” in your tags which will order it before your last UI.

See more: