Implementing specular in a shader on iOS

Hello. I need your help implementing specular lighting model on iOS. I am using a vertex color shader with alpha. Basically, it has specular params in it, but when I set everything up, specular lighting only shows up in the Editor and not on the divice. iOS is ignoring it for some reason.

Here is the code that I am using:

Shader "Alpha/VertexLit Colored" {
Properties {
    _Color ("Main Color", Color) = (1,1,1,1)
    _SpecColor ("Spec Color", Color) = (1,1,1,0)
    _Emission ("Emmisive Color", Color) = (0,0,0,0)
    _Shininess ("Shininess", Range (0.01, 1)) = 0.7
    _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
}

SubShader {
    Alphatest Greater 0
    Blend SrcAlpha OneMinusSrcAlpha 
    ColorMask RGB
    Pass {
        Material {
            Shininess [_Shininess]
            Specular [_SpecColor]
            Emission [_Emission]    
        }
        ColorMaterial AmbientAndDiffuse
        Lighting On
        SetTexture [_MainTex] {
            Combine texture * primary, texture * primary
        }
        SetTexture [_MainTex] {
            constantColor [_Color]
            Combine primary * constant DOUBLE, primary * constant
        } 
    }
}

Fallback "Specular", 1
}

Another thing, I know nothing about CG, so when I found what seems to be a solution to this (or similar) problem, I didn’t know what to do with it.

The current version of the shader doesn’t work as specular at all. I also managed to get it to show as too much specular on the device (again, looked perfect in Editor).

Just in case somebody else needs the same shaders, here are its transparent and opaque variations:

Shader "VertexColor Transparent Specular" {
Properties {
	_Shininess ("Shininess", Range (0.03, 1)) = 0.078125
	_SpecularColor("_SpecularColor", Color) = (1,1,1,0)
	_MainTex ("Base (RGBA)", 2D) = "white" {}
	_GlossColor ("_GlossColor", Color) = (1,1,1,0)
}
SubShader { 
	Tags { "Queue"="Transparent" }
	ZWrite On
	Alphatest Greater 0
	Blend SrcAlpha OneMinusSrcAlpha
	ColorMask RGB
	LOD 250
	
CGPROGRAM
#pragma surface surf MobileBlinnPhong exclude_path:prepass nolightmap noforwardadd alpha
half4 _GlossColor;
half4 _SpecularColor;

inline fixed4 LightingMobileBlinnPhong (SurfaceOutput s, fixed3 lightDir, fixed3 halfDir, fixed atten)
{
	fixed diff = max (0, dot (s.Normal, lightDir));
	fixed nh = max (0, dot (s.Normal, halfDir));
	fixed spec = pow (nh, s.Specular*128) * _GlossColor;
	
	fixed4 c;
	c.rgb = (s.Albedo * _LightColor0.rgb * diff + _LightColor0.rgb * spec * _SpecularColor.rgb) * (atten*2);
	c.a = 0.0;
	return c;
}

sampler2D _MainTex;
half _Shininess;

struct Input {
	float2 uv_MainTex;
	float4 color : COLOR;
};

void surf (Input IN, inout SurfaceOutput o) {
	fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
	o.Albedo = tex.rgb * IN.color.rgb;
	o.Alpha = IN.color.a;
	o.Specular = _Shininess;
}
ENDCG
}

FallBack "Mobile/VertexLit"
}

Opaque:

Shader "VertexColor Opaque Specular" {
    Properties {
        _Shininess ("Shininess", Range (0.03, 1)) = 0.078125
        _SpecularColor("_SpecularColor", Color) = (1,1,1,0)
        _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
        _GlossColor ("_GlossColor", Color) = (1,1,1,0)
    }
    SubShader {
        Tags { "Queue"="Geometry" }
        ZWrite On
        ColorMask RGB
        LOD 250
     
    CGPROGRAM
    #pragma surface surf MobileBlinnPhong exclude_path:prepass nolightmap noforwardadd
    half4 _GlossColor;
    half4 _SpecularColor;
     
    inline fixed4 LightingMobileBlinnPhong (SurfaceOutput s, fixed3 lightDir, fixed3 halfDir, fixed atten)
    {
        fixed diff = max (0, dot (s.Normal, lightDir));
        fixed nh = max (0, dot (s.Normal, halfDir));
        fixed spec = pow (nh, s.Specular*128) * _GlossColor;
     
        fixed4 c;
        c.rgb = (s.Albedo * _LightColor0.rgb * diff + _LightColor0.rgb * spec * _SpecularColor.rgb) * (atten*2);
            c.a = 1;
        return c;
    }
     
    sampler2D _MainTex;
    half _Shininess;
     
    struct Input {
        float2 uv_MainTex;
        float4 color : COLOR;
    };
     
    void surf (Input IN, inout SurfaceOutput o) {
        fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
        o.Albedo = tex.rgb * IN.color.rgb;
        o.Specular = _Shininess;
    }
    ENDCG
    }
     
    FallBack "Mobile/VertexLit"
    }