Low expore sun?

When I have something in the opposite direction of a directional light/sun it’s completly dark like it’s a picture shot by a camera with bad exposure. In real life, things stil lget a lot of light if it’s not in the direction of the sun. How do I get the light to “spread” more.

You can modify the Ambient Light property that is found in Edit/Render Settings.

Alternatively, if that doesn’t suit you (since it affects all objects), you can use this shader found in the surface shader lighting examples. It defines and uses a custom lighting model that makes the angle between normal and light source affect the lighting less.

Shader "Example/Diffuse Wrapped" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf WrapLambert

      half4 LightingWrapLambert (SurfaceOutput s, half3 lightDir, half atten) {
          half NdotL = dot (s.Normal, lightDir);
          half diff = NdotL * 0.5 + 0.5;
          half4 c;
          c.rgb = s.Albedo * _LightColor0.rgb * (diff * atten * 2);
          c.a = s.Alpha;
          return c;
      }

      struct Input {
          float2 uv_MainTex;
      };
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    }
    Fallback "Diffuse"
  }