Making per-object UV's in screen space

Unity Engine
1

I’m trying to make per-object camera facing UV’s that “stick to” object for NPR textures (watercolor paper, sketchmaps, etc).
I figured the best way to do that would be to transform both the objects position and its vertices into either clip space or screenspace, then subtract one from the other and use the XY results as UV coordinates.

This kind of works when I try it in clip space, but I’m getting skewing at the edges of the frame and nasty, inverting artifacts when faces are perpendicular to the camera, and the texture isn’t perfectly screen aligned.

Clearly I’m missing something - some transform or scaling factor- anybody have any suggestions?

2228×1143 108 KB

Here’s the shader:

Shader "Custom/UVObject_face_camera_2" {

    Properties {
        _debug_texture ("debug_texture", 2D) = "white" {}
        _tilingamount ("tiling amount", Range(0, 5)) = 0.03428461
    }
   
    SubShader {
        Tags {
            "RenderType"="Opaque"
            "DisableBatching"="True"
        }
       
        LOD 200
       
        Pass {
            Name "FORWARD"
            Tags {
                "LightMode"="ForwardBase"
            }
           
           
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #define UNITY_PASS_FORWARDBASE
            #include "UnityCG.cginc"
            #pragma multi_compile_fwdbase_fullshadows
            #pragma only_renderers d3d9 d3d11 glcore gles
            #pragma target 3.0
            uniform sampler2D _debug_texture; uniform float4 _debug_texture_ST;
            uniform float _tilingamount;
           
           
            float4 object_position_to_camera( float3 ObjectPosition ){
                float4 clipSpacePosition =  mul(UNITY_MATRIX_VP, ObjectPosition);
                return clipSpacePosition;
            }
           
            float4 vertex_position_to_camera( float3 InputVertices ){
                float4 clipSpaceVertices =  mul(UNITY_MATRIX_VP, InputVertices);
                return clipSpaceVertices;
            }
           
            struct VertexInput {
                float4 vertex : POSITION;
            };
           
            struct VertexOutput {
                float4 pos : SV_POSITION;
                float4 posWorld : TEXCOORD0;
            };
           
            VertexOutput vert (VertexInput v) {
                VertexOutput o = (VertexOutput)0;
                o.posWorld = mul(unity_ObjectToWorld, v.vertex);
                o.pos = UnityObjectToClipPos( v.vertex );
                return o;
            }
           
            float4 frag(VertexOutput i) : COLOR {
                float4 objPos = mul ( unity_ObjectToWorld, float4(0.0,0.0,0,1) );
                float2 vertsClipPosition = vertex_position_to_camera( i.posWorld.rgb ).rg;
                float2 objectClipPosition = object_position_to_camera( objPos.rgb ).rg;
                float2 generatedUVCoords = float2((vertsClipPosition.r - objectClipPosition.r), (objectClipPosition.g - vertsClipPosition.g));  // generate UV's by subtracting
                float2 scale_tiles =  generatedUVCoords  *_tilingamount;
                float4 _debug_texture_var = tex2D(_debug_texture, TRANSFORM_TEX(scale_tiles, _debug_texture));
                float3 finalColor = _debug_texture_var.rgb;
                return fixed4(finalColor,1);
            }
           
            ENDCG
        }
    }
   
    FallBack "Diffuse"
    CustomEditor "ShaderForgeMaterialInspector"
}
2

I would suggest using a triplanar, constant scale method, like I show here.

Unfortunately it looks like that hastebin link has expired, so I’ll have to dig up that shader again.

3

That is super cool! I’ll definitely try that - but I’m still looking for a way of getting my screen projected textures to do the right thing.

4

I plan to do that for my project lol, subscribing. I wanted to avoid the swimming on objects rotating too, which might not be possible lol.

5

If you’re adventurous, the shader I original posted was a mix of Kyle’s original and this technique (just sampling a texture rather than a noise function):
http://graphics.cs.williams.edu/papers/HashedAlphaI3D17/

Also, I forgot that Kyle’s shader doesn’t use triplanar mapping, so it’s even easier to implement. I had done triplanar for one of my tests and actually abandoned it in favor of a 3d texture for the effect I wanted…

The stretching you see in the above image is from view space being an orthographic projection. When moving the positions around subtracting the pivot will indeed keep the view space UVs stable, but the stretching across the side is unavoidable.

Using clip space accounts for perspective and will prevent stretching, but you cannot prevent the “swimming” since the projection changes as the object moves.

In short it’s impossible to have a single view based projection that both prevents stretching and swimming. If you really were firm on keeping both you would have to pick one projection (probably clip space) and apply it as “static” UVs (or a constant matrix from script) so it can be reused for several frames and then swap or blend to a new one when it gets too far. Would work for rotation then too.

But honestly the constant scale technique is a lot easier and going to be a lot nicer looking.

6

You talking about this type of effect?

7

I had try to implement this technique already in the past, I have zero mastery of projection, but didn’t unity provide a keyword like screenUV, I remember using that in early test (strumpy node). Why not offset base on that and ditch complex projection?

The second test I did was simply UVing the character in 0-1 projected space, which works well with rotation along the axis of projection, but of course you would have problem on rotation. In fact I was thinking of projecting an UV gradient and use that as a sampling for screen space texture … I have been wondering if I could use hybrid with a triplanar masking.

I don’t plan to try anytime soon though, I have other task to complete.

8

For future people who come this way looking for a solution to this problem (per-object screen facing UV’s) the answer was found here:

Shader "Custom/UVObject_face_camera_2" {
Properties {
_MainTex ("Color Texture", 2D) = "white" {}
_SSUVScale("UV Scale", Range(0,10)) = 1
}

CGINCLUDE
    sampler2D _MainTex;
    float _SSUVScale;

    struct appdata {
        float4 vertex : POSITION;
    };

    struct v2f {
        float4 pos : POSITION;
        float4 pos2: TEXCOORD0;
    };



    float2 GetScreenUV(float2 clipPos, float UVscaleFactor)
    {
        float4 SSobjectPosition = UnityObjectToClipPos (float4(0,0,0,1.0)) ;
        float2 screenUV = float2(clipPos.x,clipPos.y);
        float screenRatio = _ScreenParams.y/_ScreenParams.x;

        screenUV.x -= SSobjectPosition.x/(SSobjectPosition.w);
        screenUV.y -= SSobjectPosition.y/(SSobjectPosition.w);

        screenUV.y *= screenRatio;

        screenUV *= 1/UVscaleFactor;
        screenUV *= SSobjectPosition.z;

        return screenUV;
    };




ENDCG

SubShader {
      Tags { "RenderType" = "Opaque" 
            "DisableBatching"="True"
     }

      Pass
    {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        v2f vert(appdata v) {              
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex);
            o.pos2 = o.pos;

            return o;
        }      

        half4 frag(v2f i) :COLOR
        {               
            float2 screenUV = GetScreenUV(i.pos2.xy/ i.pos2.w, _SSUVScale);
            half4 screenTexture = tex2D (_MainTex, screenUV);

            return screenTexture;
        }
        ENDCG               
    }

}
Fallback "Diffuse"
}
1 Like
9

@bgolus - I’m trying to figure out your constant scale technique. Do you have any examples that I could look at?
Thanks!

10

I couldn’t find my original example shader from that twitter post, so this is a little different in implementation. That original twitter thread I was using a constant scaling technique I wrote, and in this one I’m using the method from the Hashed Alpha Testing link I posted above. For Dino Frontier I ended up using something more like this, but I think my original implementation looks a little better for this use case.

Anyway, I’d go grab the example project from Kyle’s tutorial page and try using this shader in the demo scene.

// Modified shader from http://kylehalladay.com/blog/tutorial/2017/02/21/Pencil-Sketch-Effect.html
Shader "Unlit/SingleObjectHatchConstantScale"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Hatch0("Hatch 0", 2D) = "white" {}
        _Hatch1("Hatch 1", 2D) = "white" {}

    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            Tags{ "LightMode" = "ForwardBase" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
                       
            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 norm : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
                float3 nrm : TEXCOORD1;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float4 _MainTex_TexelSize;

            sampler2D _Hatch0;
            sampler2D _Hatch1;
            float4 _Hatch0_TexelSize;
            float4 _Hatch1_TexelSize;

            float4 _LightColor0;
           
            v2f vert (appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv * _MainTex_ST.xy + _MainTex_ST.zw;
                o.nrm = mul(float4(v.norm, 0.0), unity_WorldToObject).xyz;
                return o;
            }

            // modified from http://graphics.cs.williams.edu/papers/HashedAlphaI3D17/
            fixed4 tex2DConstScale(sampler2D tex, float texSize, float2 uv)
            {
                // Find the discretized derivatives of our coordinates
                float maxDeriv = max( length(ddx(uv)), length(ddy(uv)) );
                float pixScale = 1.0 / (texSize * maxDeriv);
                // Find two nearest log-discretized noise scales
                float2 pixScales = float2(
                    exp2(floor(log2(pixScale))),
                    exp2( ceil(log2(pixScale)))
                    );
                // Factor to interpolate lerp with
                float lerpFactor = frac( log2(pixScale) );

                return lerp(
                    tex2D(tex, pixScales.x * uv),
                    tex2D(tex, pixScales.y * uv),
                    lerpFactor
                    );
            }

            fixed3 Hatching(float2 _uv, half _intensity)
            {
                half3 hatch0 = tex2DConstScale(_Hatch0, _Hatch0_TexelSize.z, _uv).rgb;
                half3 hatch1 = tex2DConstScale(_Hatch1, _Hatch1_TexelSize.z, _uv).rgb;

                half3 overbright = max(0, _intensity - 1.0);

                half3 weightsA = saturate((_intensity * 6.0) + half3(-0, -1, -2));
                half3 weightsB = saturate((_intensity * 6.0) + half3(-3, -4, -5));

                weightsA.xy -= weightsA.yz;
                weightsA.z -= weightsB.x;
                weightsB.xy -= weightsB.zy;

                hatch0 = hatch0 * weightsA;
                hatch1 = hatch1 * weightsB;

                half3 hatching = overbright + hatch0.r +
                    hatch0.g + hatch0.b +
                    hatch1.r + hatch1.g +
                    hatch1.b;

                return hatching;

            }

           
            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 color = tex2D(_MainTex, i.uv);
                fixed3 diffuse = color.rgb * _LightColor0.rgb * dot(_WorldSpaceLightPos0, normalize(i.nrm));

                fixed intensity = dot(diffuse, fixed3(0.2326, 0.7152, 0.0722));

                color.rgb =  Hatching(i.uv * 8, intensity);

                return color;
            }
            ENDCG
        }
    }
}
1 Like
11

Thanks very much! I’m going to spend some time pulling it apart and understanding how it works. Lots to learn here!

12

Hey everyone,

I am currently trying to sample a texture in screen space and it works well. But I would like to be able to constrain uv position and scale based on object’s position and distance from camera. I found this post and other examples but I also faced some issues and for the moment I don’t see how to fix them.

I made another subject with code examples and a gif here : per-object screen space uv issue

Thanks a lot !

13

I’ve been trying to make sense of how the camera facing uvs are calculated in that very sample but for the life of me I don’t understand how.

I’m very new to shaders and have a library of sub graphs i’m using as reusable functions in shader graph and so I’m trying to create that pencil effect in shader graph.

I can make it work as an object shader and can get this effect in a custom blit render feature:

6275183--693215--upload_2020-9-3_18-4-56.png

So the last piece of the puzzle for me is to figure out the camera facing uvs in shader graph but I’m having a really hard time understanding what’s happening. How are the UVs being sampled in the replacement shader and how can I do the same with shader graph?

14

Because it doesn’t use camera facing UVs. It uses the mesh’s default UVs. My alternative shader scales the UVs so the texture is roughly constantly sized in screen space. But it’s still using the mesh UVs. The whole thing with that example shader was to show you didn’t necessarily need screen space UVs.

Now, for Shader Graph, if you do just want screen space UVs, you can use the screen position node.