My transparency shader isn't working on my terrrain. It's black where it should be transparent.

Unity Engine
1

The idea is that the alpha is supposed to approach 0 as a part of the terrain reaches 0 on the Y axis. Unfortunately, it’s just black.

705×434 55.1 KB

Shader code: Shader "Unlit/unlit"{ Properties { _MainTex ("Texture", 2D) = "white" { - Pastebin.com

2

Hi,

when you are under 0 your alpha will be negative. You can clamp it between 0 and 1 to have your effect. Your shader give that :

Shader "Unlit/unlit"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
        SubShader
    {
        Tags { "RenderType"="Transparent" "Queue"="Transparent" "IgnoreProjector"="True"}
        LOD 100

        ZWrite off
        Blend SrcAlpha OneMinusSrcAlpha
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            #pragma enable_d3d11_debug_symbols
            #include "UnityCG.cginc"
            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };
            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 worldPos : TEXCOORD1;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };
            sampler2D _MainTex;
            float4 _MainTex_ST;
          
            v2f vert (appdata v)
            {
                v2f o;
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }
          
            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                if (i.worldPos.y > 1.0) {
                    col.a = 1.0;
                }
                else {
                    col.a = i.worldPos.y;
                }

                // clamp col.a to avoid negative value
                col.a = clamp (col.a,0,1);
                return col;
            }
            ENDCG
        }
    }
}

And you don’t need the alpha pragma in vertex fragment, it’s for surface shader.

1 Like
3

Thanks a ton, man.

1 Like