Offset value not responsive in secondary texture

Questions & Answers
1

Hi. I am trying to use a vertex displacement shader to animate a bulge moving along a pipe. Everything was working fine until I tried to pan the displacement map (a white horizontal line on a black background) vertically along the UV’s. I tried using the following script to adjust the displacement map’s offset.

#pragma strict

var scrollSpeedX = 0.0;
var scrollSpeedY = 0.5;

var rend : Renderer;

function Start(){

	rend = GetComponent.<Renderer>();

}

function FixedUpdate(){

	var offsetX = Time.time * scrollSpeedX;
	var offsetY = Time.time * scrollSpeedY;
	rend.material.SetTextureOffset("_DispTex", Vector2(offsetX, offsetY));
}

At runtime, the offset values change on the material in the inspector, but I do not see any results on my object. Even stranger, when I manually adjust the tiling and offset values in the editor, nothing happens either. However, the tiling and offset values do work on the main texture. Here is the shader I cobbled together. The displacement itself works fine.

  Shader "VertexDisplace" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _DispTex ("Displacement Map", 2D) = "gray" {}
      _Displacement ("Displacement", Range(0, 1.0)) = 0.3

    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma target 3.0
      #pragma surface surf BlinnPhong addshadow fullforwardshadows vertex:vert nolightmap

       struct appdata {
                float4 vertex : POSITION;
                float4 tangent : TANGENT;
                float3 normal : NORMAL;
                float2 texcoord : TEXCOORD0;
            };

      sampler2D _DispTex;
      float _Displacement;


      void vert (inout appdata_full v) {
      	  float d = tex2Dlod(_DispTex, float4(v.texcoord.xy,0,0)).r * _Displacement;
          v.vertex.xyz += v.normal * d;
      }

      struct Input {
          float2 uv_MainTex;
          float2 uv_DispTex;
      };

      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
      }
    }

Here is an image of the object in question and the displacement map to clarify the effect I’m trying to achieve. The deformation works but I want it to pan up along the pipe. This is the first time I’ve messed with shaders in Unity so hopefully I’m just missing something simple yet fundamental. Any thoughts would be greatly appreciated!

76761-tube.png

76762-line.png

2

Shader “VertexDisplace” {
Properties {
_MainTex (“Texture”, 2D) = “white” {}
_DispTex (“Displacement Map”, 2D) = “gray” {}
_Displacement (“Displacement”, Range(0, 1.0)) = 0.3

     }
     SubShader {
       Tags { "RenderType" = "Opaque" }
       CGPROGRAM
       #pragma target 3.0
       #pragma surface surf BlinnPhong addshadow fullforwardshadows vertex:vert nolightmap
 
        struct appdata {
                 float4 vertex : POSITION;
                 float4 tangent : TANGENT;
                 float3 normal : NORMAL;
                 float2 texcoord : TEXCOORD0;
             };
 
       sampler2D _DispTex;
       float4 _DispTex_ST;
       float _Displacement;
 
 
       void vert (inout appdata_full v) {
             float2 uv = TRANSFORM_TEX (v.texcoord.xy, _DispTex);
             float d = tex2Dlod(_DispTex, float4(uv,0,0)).r * _Displacement;
           v.vertex.xyz += v.normal * d;
       }
 
       struct Input {
           float2 uv_MainTex;
       };
 
       sampler2D _MainTex;
       void surf (Input IN, inout SurfaceOutput o) {
           o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
       }
       ENDCG
       }
     }

By default you are just using the uv coordinates of the object without transformation, so the texture offset values won’t do anything. These are automatically generated in a surface shader in the Input struct, however you need to do it yourself in a vertex program.

3

Thanks so much! This worked perfectly. It makes sense that the vertex function would need that information.