Question about my simple edit of the default shader

Unity Engine
1

Hello all. I’m getting started with alpha shaders. I decided to edit the default shader to learn how it works.

This code is supposed to take two textures, a Main Texture, and an Alpha Map. The Alpha Map just sets the alpha of the main texture.

Question 1: How does the program know how to hook 2D _MainTex with Sampler2D _MainTex? Is it ‘proper’ to have same names? Is uv_MainTex automatic as well?
Question 2: I’m passing in AlphaTexture’s rgba values, when all I need are the a values. How do I only pass the alpha values?
Question 3: What am I missing from here to make this work?

Shader "Custom/TextureAlpha" {
	Properties {
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_AlphaTex ("Alpha Map",2D) = "white"{}
	}
	SubShader {
		Tags { "RenderType"="Opaque" }
		LOD 200
		
		CGPROGRAM
		#pragma surface surf Lambert

		sampler2D _MainTex;
		sampler2D _AlphaTex;

		struct Input {
			float2 uv_MainTex;
			float2 uv_AlphaTex;
		};

		void surf (Input IN, inout SurfaceOutput o) {
			half4 c = tex2D (_MainTex, IN.uv_MainTex);
			half4 d = tex2D (_AlphaTex,IN.uv_AlphaTex);
			o.Albedo = c.rgb;
			o.Alpha = d.a;//c.r+c.g+c.b;+d.a;
		}
		ENDCG
	} 
	FallBack "Diffuse"
}

Thanks!

2

Having the same name (and appropriate type) is the only way to get your properties into your shader when it’s executing. The automatic UV calculation (taking scaling and offset into account) is done only in surface shaders like yours, when you add the appropriately named input structs (uv2 works too). In a regular vertex/fragment shader, you need to do the calculations yourself by declaring the automatically filled TextureName_ST fields, like in this example.

On real graphics cards (i.e. not mobile chipsets), reading a 4-component vector incurs no more cost than reading a single float. Also, the compiler is usually clever enough to ignore values that you aren’t using. However, you can make it explicit by changing your code to this:

            half d = tex2D (_AlphaTex,IN.uv_AlphaTex).a;

            o.Albedo = c.rgb;

            o.Alpha = d;

Finally, you should make sure that the texture you’re using as _AlphaTex is imported in the alpha-only (Alpha 8) format.

You’ll have to be more specific about what isn’t working.

3

I think what isn’t working is alpha blending, which is off by default in surface shaders.
To enable standard alpha blending change:
#pragma surface surf Lambert
to
#pragma surface surf Lambert alpha

then you should change the render queue to transparent, like this
Tags { “Queue” = “Transparent” }

And finally turn off ztest off, though that may be automatic with “alpha” flag, not sure.

4

ZTest is turned off by the alpha surface parameter. The only thing you need to add manually are tags, which should be the following for most transparent shaders:

Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
5

Thank you both for your answers!

Both #pragma surface surf Lambert alpha and the Tags were important for getting the effect I wanted. Looks like there’s quite a bit of research to be done!