Surface shader does not write alpha value

Unity Engine
1

Using Unity 5.1.0f3.

I have a scene with a RenderTexture set as target to a Camera. There’s also a script attached to the camera, that exports the RenderTexture to a PNG.

Objects using the new standard shader are rendered properly, opaque or transparent.

However, when using a custom surface shader, as soon as my shader has “alpha” as surface shader parameter, the shader stops writing alpha values to the RenderTexture.

Scene view & Camera preview

2165167--143183--CameraPreview.png
2165167--143183--CameraPreview.png648×595 94.1 KB

Resulting PNG:
2165167--143184--GeneratedTexture.png

What can I do to make the shader render the alpha values to the RenderTexture? Is this a bug or some weird surface shader limitation? I want to avoid having to write all the shaders again as CG shaders and figuring out all the lighting and shadow stuff.

I attached my simple test project as a UnityPackage.

Here’s the shader code:

Shader "Custom/TestShader"
{
   Properties
   {
     _Color ("Tint Color", Color) = (1,1,1,1)
     _MainTex ("Main Texture", 2D) = "white" {}
   }

   SubShader
   {
     Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" }
     LOD 200
    
CGPROGRAM
     #pragma surface surf Lambert alpha
     #pragma fragmentoption ARB_precision_hint_fastest
    
     fixed4 _Color;
     sampler2D _MainTex;        

     struct Input
     {
       float2 uv_MainTex : TEXCOORD0;
     };
    
     void surf (Input IN, inout SurfaceOutput o)
     {
       fixed4 col = _Color * tex2D(_MainTex, IN.uv_MainTex);
       o.Albedo = col.rgb;
       o.Alpha = col.a;
     }
ENDCG
   }
   Fallback "Diffuse"
}

Changing the line
#pragma surface surf Lambert alpha
to
#pragma surface surf Lambert
makes the items render fully but without transparency.

2165167–143180–RenderTextureSurfaceAlpha.unitypackage (119 KB)

2

Everything looks fine to me, but there are two things you might want to check:

  1. Make sure your camera has a clear color (unless you had something else in mind)
  2. Discard fully transparent pixels from your shader*
  • What I mean by this is that even your fully transparent pixels with alpha working correctly will go on to the lighting stage unless you discard them. There’s a way to do it with shader properties (AlphaTest or something), but I do it with code in the shader. You can add something like this to your surface shader “surf”:
if (col.a < 0.05f)
{
    discard;
}
3
  1. The pink in the camera preview is the clear color.
  2. I’m not sure how discarding would help, the problem is that no matter what I set the alpha value to in my shader, it’s ignored.
4

Try removing “alpha” from

#pragma surface surf Lambert alpha

and add this inside the subshader (line 14ish in your code block):

Blend SrcAlpha OneMinusSrcAlpha
5

That was actually one of the first things I tried. Removing “alpha” just makes the objects opaque and the Blend parameter has no effect.

6

Actually, doesn’t seem to be related to RenderTexture. I tried using Texture2D.ReadPixels to read directly from the screen and the shader still doesn’t write alpha.

7

Have you added “keepalpha” ? The documentation mentions that only opaque shaders will default to writing 1 to the alpha value, but it might fix the issue here.

Under the transparency section.

8

Doesn’t affect the outcome. Says it’s for opaque shaders too.

9

I believe the problem you are facing here is that for transparent surface shaders Unity automatically masks out the alpha channel using ‘ColorMask RGB’. This means the alpha channel/component is never rendered to in the screen buffer or rendertexture.

I’m unsure if you can fix this directly within surface shaders, but you can fix it by using pre-compiled versions of the shaders. If you need to use the default Unity shaders then download the ‘built-in shaders’ pack from Unity for the version you are using, then

  1. Create or add shader to Unity Project.
  2. Select shader.
  3. In the inspector click on ‘Show Generated code’
  4. In MonoDevelop when it opens the compiled shader, do select all and copy.
  5. Create a new shader, give it an appropriate name.
  6. Paste the compiled shader into this one, remember to make sure its using a unique shader name.
  7. Search for ‘ColorMask RGB’ and replace with ‘ColorMask RGBA’, or actually you could probably just comment it out completely.
  8. Profit!

Obviously its quite a bit of a pain, not sure if there is an easier way, but at least it only applies to transparent shaders. Be careful when copying compiled shader code that the shader is set up to generate all permutations and api versions you’ll need.

1 Like
10

Yeah, but thought it would be worth a try regardless. I think Noisecrime’s got a very intuitive thought. I would think that’s quite likely to be the issue.

11

Well I ended up using my old CG shader in this situation, but I’d really like a dev explanation on why it’s like this with surface shaders.

12

Having checked it would appear the ColorMask setting is solely due to legacy reasons and Unity’s old alpha-based glow technique. Hopefully this means it will be addressed in future release and removed or made optional.

13

I just hit my face with this issue. This is still happening. Any clues?

14

I have the same problem. My custom shaders aren’t drawing to the alpha in rendertextures and my objects are invisible. Does writing pure CG shaders fix this?

Why doesn’t Unity provide a decent set of mobile shaders?!?! I don’t want frickin’ physically based uber-real objects in my mobile game. I want normal mapped sprites that can be used for efficient rendering using the full range of techniques. Years on from 2D mode and 2D is still an uphill struggle with problem after problem caused by lack of attention from Unity. It really wouldn’t take them long to put together a batch of mobile optimised shaders to match the capabilities of the past few years of devices.

15

I had the same problem and I found a solution. Just add a simple pass ColorMask A to write what you want to write in the alpha channel.

SubShader {
        Pass
        {
            Tags
            {
                "Queue" = "Transparent"
                "IgnoreProjector" = "True"
                "RenderType" = "Transparent"
                "PreviewType" = "Plane"
                "CanUseSpriteAtlas" = "True"
            }

            Cull Off
            Lighting Off
            ZWrite Off
            Blend One OneMinusSrcAlpha
            ColorMask A

            CGPROGRAM
            #pragma vertex SpriteVert
            #pragma fragment frag
            #pragma target 2.0
            #include "UnitySprites.cginc"

            fixed4 frag(v2f IN) : SV_Target
            {
                fixed4 c = SampleSpriteTexture(IN.texcoord);
                return c;
            }
            ENDCG
           
        }
       
        Tags {
            "RenderType"="Transparent"
            "Queue" = "Transparent"
        }
        LOD 200
       
        Blend One OneMinusSrcAlpha
        ZWrite Off
        Cull Off
        ColorMask RGB

        CGPROGRAM
        // Physically based Standard lighting model, and enable shadows on all light types
        #pragma surface surf Standard fullforwardshadows alpha:fade alpha:auto  //vertex:vert
16

Just bumped into the issue.
When adding

alphatest:_Cutoff

the result alpha channel is empty. But making a manual discard like this:

clip(c.a-_Cutoff);

fixes the issue.

Have no idea why…

17

Thanks for this post! I had the same problem in my old Unity 5.6.
My surface shader tend to skip alpha for my render texture. Although the camera rendered the object correctly to the editor small window || directly to screen. Adding alpha || alpha:fade || others options inside shader had incorrect rendering. So, i’ve tried the solution posted by by Noisecrime. It worked out. Indeed, Mask RGB to Mask RGBA is an elegant solution.