transparent shaded side of object

Hi! Im not familiar with shaders, but want to know - is it possible to create shader that makes transparent shaded part of object? 61048-shader.png

On left side standard shader, on right side is what i want to create; dark side on left image is transparent on right image.

Sure, a transparent shader that uses the light that hits the object to compute the alpha (instead of applying it to the rgb the color) can do this, i.e.

Shader "Custom/Transparent Light"{
	Properties{
		_Color("Color", Color) = (1.0, 1.0, 1.0, 1.0)
	}
		SubShader{
		Pass{
		Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
		ZWrite Off
		Blend SrcAlpha OneMinusSrcAlpha

		CGPROGRAM

#pragma vertex vert
#pragma fragment frag


		uniform float4 _Color;
	uniform float4 _LightColor0;

	struct toVert {
		float4 vertex : POSITION;
		float3 normal : NORMAL;
	};
	struct vertToFrag {
		float4 pos : SV_POSITION;
		float4 color: COLOR;
	};

	vertToFrag vert(toVert input)
	{
		vertToFrag o;

		float3 normalDirection = normalize(mul(float4(input.normal, 0.0), _World2Object).xyz);
		float3 lightDirection;
		float atten = 1.0;

		lightDirection = normalize(_WorldSpaceLightPos0.xyz);

		float3 diffuseReflection = atten*_LightColor0.xyz*max(0.0, dot(normalDirection, lightDirection));
		float alpha = (diffuseReflection.r + diffuseReflection.g + diffuseReflection.b)/3;

		o.color = float4(_Color.rgb, alpha);

		o.pos = mul(UNITY_MATRIX_MVP, input.vertex);
		return o;
	}

	float4 frag(vertToFrag input) : Color
	{
		return input.color;
	}
		ENDCG

	}
	}Fallback "Mobile/Diffuse"
}

61135-transparent.png