Trying to turn off fog in this Toon/Lit shader

I’ve got to be doing something wrong. I’ve got the standard Toon/Lit shader on an object. I right click it in the inspector and go to “Edit shader…” which opens it up in MonoDevelop. I add “Fog { Mode Off }” to the SubShader and save it as a separate “Toon/Lit-noFog.shader” file. Here’s the full shader code:

Shader "Toon/Lit-noFog" {
	Properties {
		_Color ("Main Color", Color) = (0.5,0.5,0.5,1)
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_Ramp ("Toon Ramp (RGB)", 2D) = "gray" {} 
	}

	SubShader {
		Fog { Mode Off }
		Tags { "RenderType"="Opaque" }
		LOD 200
		
CGPROGRAM
#pragma surface surf ToonRamp 

sampler2D _Ramp;

// custom lighting function that uses a texture ramp based
// on angle between light direction and normal
#pragma lighting ToonRamp exclude_path:prepass
inline half4 LightingToonRamp (SurfaceOutput s, half3 lightDir, half atten)
{
	#ifndef USING_DIRECTIONAL_LIGHT
	lightDir = normalize(lightDir);
	#endif
	
	half d = dot (s.Normal, lightDir)*0.5 + 0.5;
	half3 ramp = tex2D (_Ramp, float2(d,d)).rgb;
	
	half4 c;
	c.rgb = s.Albedo * _LightColor0.rgb * ramp * (atten * 2);
	c.a = 0;
	return c;
}


sampler2D _MainTex;
float4 _Color;

struct Input {
	float2 uv_MainTex : TEXCOORD0;
};

void surf (Input IN, inout SurfaceOutput o) {
	half4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
	o.Albedo = c.rgb;
	o.Alpha = c.a;
}
ENDCG

	} 

	Fallback "Diffuse"
}

Can anyone tell me what I’m doing wrong here? From all the threads I’ve read this seems like it should work, but no dice.

Thanks!

Woops, ok so I added “nofog” to the pragma line and it works now - sorry for the preemptive post… should’ve kept searching!