Unity 5 standard shader support for vertex colors?

Questions & Answers
1

Hello!
I want to bake light with enlighten but I find that I only can do it with the standard shader that doesn’t support vertex color input. Is there any workaround for this? Is this supported in a later update?

2

You can get vertex colors to work with the standard shader (PBR stuff) by making a new Shader. Add vertex:vert to the pragma line in the CGPROGRAM block. You can then add a vertex function to get the vertex color, and then pass that into the surface function to use for the albedo:

Shader "Custom/StandardVertex" {
	Properties {
		_Color ("Color", Color) = (1,1,1,1)
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0
	}
	SubShader {
		Tags { "RenderType"="Opaque" }
		LOD 200
		
		CGPROGRAM
		#pragma surface surf Standard vertex:vert fullforwardshadows
		#pragma target 3.0
		struct Input {
			float2 uv_MainTex;
			float3 vertexColor; // Vertex color stored here by vert() method
		};
		
		struct v2f {
		  float4 pos : SV_POSITION;
		  fixed4 color : COLOR;
		};

		void vert (inout appdata_full v, out Input o)
		{
			UNITY_INITIALIZE_OUTPUT(Input,o);
			o.vertexColor = v.color; // Save the Vertex Color in the Input for the surf() method
		}

		sampler2D _MainTex;

		half _Glossiness;
		half _Metallic;
		fixed4 _Color;

		void surf (Input IN, inout SurfaceOutputStandard o) 
		{
			// Albedo comes from a texture tinted by color
			fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
			o.Albedo = c.rgb * IN.vertexColor; // Combine normal color with the vertex color
			// Metallic and smoothness come from slider variables
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
		}
		ENDCG
	} 
	FallBack "Diffuse"
}

The full Standard Shader is a big can of worms. Not sure how any of it works at the moment so I can’t include this yet.

3

If anyone is still looking for standard shader with such functionality you should check out this thread: http://forum.unity3d.com/threads/standard-shader-with-vertex-colors.316529/

4

You can install Unity ProBuilder in your project, then create a new material with uses the ProBuilder/Diffuse Vertex Color shader