VideoPlayer Tiling?

Hi All,

I'm using the new VideoPlayer component to display a monoscopic 2D video (360 on Android). I need to adjust the tiling (eg set Y to -1 to flip the texture) but on playing the VideoPlayer resets this to 1 when playing, then sets it back to -1 when I stop the app.

I found another thread where someone asked about this and is having the same issue but there appears to be no answer just a workaround...

http://answers.unity3d.com/questions/1366010/video-player-as-texture-cant-set-tiling.html

Is it a bug that the VideoPlayer sets the tiling? Is there any way to stop it from doing so?

I note the response above that one can edit shaders, but that didn't work for me (not sure why yet). I also note that I can use "GoogleVR/Video Unlit Shader" and this correctly flips the texture - but the quality of the video using this texture seems quite poor (at least when used for 360).

I'll likely be learning how to edit shaders in the next few days but wondered if this issue is by design or is a bug or if anyone knew any way to fix this without editing the shader.

Thanks in advance :-)

Inspired by the other thread mentioned above (which unfortunately I couldn't get working for some reason) and the source of the GoogleVR/Unlit Video Shader, here is the shader that works for me which is a copy of the Unlit/Texture shader with a "Flip Y" option... It doesn't flip normals as the model I'm using already has normals flipped, but to do that I think you simply add "Cull Front" to Pass, please correct me if I'm wrong.

Shader "Unlit/UnlitVideo"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        [Toggle(FLIP_Y)] _FlipY ("Flip Y", Float) = 0
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            #pragma multi_compile ___ FLIP_Y

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);

                #ifdef FLIP_Y // Inspired by GoogleVR/Video Unlit Shader
                    v.uv.y = 1.0 - v.uv.y;
                #endif  // FLIP_Y

                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return col;
            }
            ENDCG
        }
    }
}