Edge seam issue when sampling 4-in-one texture

[aldrickbanks]

I am using 2 4-in-one texture and 2 RGBA weight maps to realize the effect which usually needs 8 textures to save some semantics and a second draw call in Unity’s default terrain engine.

When I test it in terrain shader and in regular scene architecture shader, the basic mechanism works, but the edge of each texture shows a weird dotted seam line :

The UV tweak codes are like this. I only show sampling the first 4-in-one texture cuz it is the same for the second one:

        void MP_SplatmapMix(Input IN, out fixed4 mixedDiffuse)
        {

        //////////////////////////////////////////////
        /////////first 4-in-one texture/////
        //////////////////////////////////////////////
            mixedDiffuse = 0.0;
            fixed4 c1 = tex2D(_MainTex, (IN.uv_MainTex  - floor(IN.uv_MainTex))/ 2.0);
            float2 uvnew  = float2((IN.uv_MainTex.x  + 1.0 - floor(IN.uv_MainTex.x))/ 2.0,(IN.uv_MainTex.y  - floor(IN.uv_MainTex.y))/ 2.0);
            fixed4 c2 = tex2D(_MainTex,uvnew);
            uvnew = float2((IN.uv_MainTex.x  - floor(IN.uv_MainTex.x))/ 2.0,(IN.uv_MainTex.y  + 1.0 - floor(IN.uv_MainTex.y))/ 2.0);
            fixed4 c3 = tex2D(_MainTex, uvnew);
            fixed4 c4 = tex2D(_MainTex, (IN.uv_MainTex  + 1.0 - floor(IN.uv_MainTex))/ 2.0);

        ////////////////////////////////////////////////////////////////////////
        /////////composite with a RGBA weight texture//
        ////////////////////////////////////////////////////////////////////////
            fixed4 alpha = tex2D(_AlphaTex1, IN.uv_AlphaTex1);
            half alpha3 =  max(alpha.g - alpha.r - alpha.b,0.0);
            half alpha2 = max(alpha.r - alpha.b,0.0);
            half alpha4 = alpha.b;
            half alpha1 = 1.0 - saturate(alpha2 + alpha3 + alpha4);
            mixedDiffuse.rgb = c1.rgb * alpha1 + c2.rgb * alpha2 + c3.rgb * alpha3 + c4.rgb * alpha4;
            mixedDiffuse.a = 1.0;
        }

The textures look like this:

Does anyone have an idea of why is this dotted edge line appearing?

[bgolus]

I just wrote a bunch about the same kind of issue here:

Strange render artifact: dotted white lines along quad borders

Whenever you see frac() used anywhere near UVs, that’s the problem. GPUs determine the mip level to use for a texture by how much the UVs change from one pixel to another. These are called screen space partial derivatives. If you use frac() it means between two pixels the UV coordinate might be going from 0.99 to 0.01, which is a huge jump and will cause the GPU to think it needs to use to the smallest mip map. “But wait” I hear you thinking, “the vertex values are all within 0.0 and 1.0, and…

You’re not directly using the frac() function in your shader, but you are still doing the same thing since this is how that function is implemented:
float frac(float x) { return x - floor(x); }
Look familiar?

You’ll want to use the tex2Dgrad solution I mention in the above post. You’ll also want to add some gutters between the 4 textures so the UVs you’re wrapping at aren’t right on the edge, otherwise you’ll always have some amount of bleed. And you may want to limit the mip levels allowed, either by limiting the derivatives passed to tex2Dgrad, or by using the recently added mip count limits.

[aldrickbanks]

@bgolus

…You’ll want to use the tex2Dgrad solution I mention in the above post.

You’ll also want to add some gutters between the 4 textures so the UVs you’re wrapping at aren’t right on the edge, otherwise you’ll always have some amount of bleed.

And you may want to limit the mip levels allowed, either by limiting the derivatives passed to tex2Dgrad, or by using the recently added mip count limits.

bgolus, thank you. The first two suggestions from you both work. I keep the uv 0.002 away from the border(tried 0.001, which seemed not enough to end the seam):

        float2 copyUV = IN.uv_MainTex;
        if( frac(copyUV.x ) > 0.998 && frac(copyUV.x) <= 1.0)
        {copyUV.x = floor(copyUV.x) + 0.998; }

        if( frac(copyUV.y ) > 0.998 && frac(copyUV.y) <= 1.0)
        {copyUV.y = floor(copyUV.y) + 0.998;}

        if( frac(copyUV.x ) >= 0.0 && frac(copyUV.x) <= 0.002)
        {copyUV.x = floor(copyUV.x) + 0.002; }

        if( frac(copyUV.y ) >= 0.0 && frac(copyUV.y) <= 0.002)
        {copyUV.y = floor(copyUV.y) + 0.002; }

        IN.uv_MainTex = copyUV;

Then the UV change rate calculation:

        float2 dx = ddx(frac(IN.uv_MainTex / uvscale));
        float2 dy = ddy(frac(IN.uv_MainTex / uvscale));
        float2 uvnew = (IN.uv_MainTex - floor(IN.uv_MainTex))/ 2.0;
        float4 c1 = tex2Dgrad(_MainTex, uvnew, dx, dy); //choose lod based on UV's change rate
        //float4 c1 = tex2D(_MainTex, uvnew);

Result(dark area is lightmapped,not an issue):

So far no problem occurs,so I haven’t tried limiting mipmap level yet.

Found in the forum for a while that you have in-depth knowledge of computer graphics,do you major in computer graphics in college:)?

cheers

[bgolus]

@aldrickbanks

Found in the forum for a while that you have in-depth knowledge of computer graphics,do you major in computer graphics in college:)?

Nope. Was working on a degree in fine arts and dropped out before I finished. My graphics programming knowledge is self taught and from working with others who I could learn from.